XLOOKUP は、Excel で情報を検索するための関数です。
従来から使われている VLOOKUP よりも使いやすく、多くの場面で活用できます。
この記事では、XLOOKUP の構文や引数、実際の使用例を初心者向けに分かりやすく解説します。
VLOOKUP と XLOOKUP の違いはこちらの記事で紹介しています。
XLOOKUP とは
XLOOKUP は、指定した値を検索し対応する値を取得する関数です。
VLOOKUP では対応が面倒な、以下の内容などが改善されています。
・ 左端以外での検索
・ エラー処理
・ 下からの検索
・・・
Microsoft 365、Excel 2021 以降で使用可能となったため、古いバージョンで作成された Excel ファイルには VLOOKUP が使用されていることが多いです。
XLOOKUP の構文
XLOOKUP の構文と各引数の説明です。
基本的な検索であれば第三引数までで使用可能ですが、第四引数まで覚えておくとかなり使えます。
構文
XLOOKUP ( 検索値, 検索範囲, 戻り範囲, [一致しなかった場合], [一致モード], [検索モード] )
※ [ ] は省略可能
例)
= XLOOKUP ( "1", A1:A10, B1:B10 )
= XLOOKUP ( A1, B1:B100, D1:D100, "一致なし" )
= XLOOKUP ( A1, 社員表!C:C, 社員表!E:E, , -1 )
| 引数 | 内容 | 必須 |
|---|---|---|
| 検索値 | 探したい値 | ○ |
| 検索範囲 | 検索するセル範囲 | ○ |
| 戻り範囲 | 取得するセル範囲 | ○ |
| 一致しなかった場合 | 検索範囲に検索値がない場合の表示 | 任意 |
| 一致モード | 完全一致・部分一致など | 任意 |
| 検索モード | 上から・下から検索 | 任意 |
基本的な使い方
社員番号から社員名を取得するサンプルを作成します。
A2 セルに入力された社員番号を社員表から検索して社員名を取得します。
社員表を別シートに作成して列指定するとさらにわかりやすい使い方ができます。
第三引数までが必須項目となります。
= XLOOKUP ( A2, A6:A15, B6:B15 )
= VLOOKUP ( A2, A6:A15, 2, FALSE )
別シートの社員表を参照する場合
= XLOOKUP ( B3, 社員表!A:A, 社員表!B:B )
第四引数「一致しなかった場合」
第四引数は、検索結果が存在しない場合の表示を指定できます。
VLOOKUP では IFERROR 関数が必要でしたが、XLOOKUP では標準で対応しています。
指定する内容は “” で囲った文字列でもよいですし、セルを参照することもできます。
= XLOOKUP ( A2, A6:A15, B6:B15, "該当なし" )
= XLOOKUP ( A2, A6:A15, B6:B15, A1 )
= IFERROR ( VLOOKUP ( A2, A6:A15, 2, FALSE ), "該当なし" )
第五引数「一致モード」
第五引数は、検索方法を指定します。
指定しなかった場合は「0 ： 完全一致」となるので、あまり使うことはありません。
なお、VLOOKUP の第四引数とは異なり、完全一致 (FALSE)、近似一致 (TRUE) だけではなく以下となります。
※ 近似一致は、検索値と完全に一致するデータがない場合、検索値以下で最も近い値を返します。
XLOOKUP では VLOOKUP になかった「完全一致、なければ次に大きい値」、「ワイルドカード検索」が追加されています。
第四引数が不要な場合は、第四引数を省略して書くこともできます。
注意事項としては「0 ： 完全一致」以外を指定した場合、検索範囲の値が昇順に並んでいないと正しい値が取得できない場合がありますので、検索範囲を昇順に並べて使用することをおすすめします。
= XLOOKUP ( A2, A6:A15, B6:B15, "該当なし", -1 )
= XLOOKUP ( A2, A6:A15, B6:B15, , 1 )
※ 第四引数を省略する場合は、カンマをふたつ並べて書きます
= VLOOKUP ( A2, A6:A15, 2, TRUE )
= VLOOKUP ( A2, A6:A15, 2, FALSE )
※ VLOOKUP では「完全一致、なければ次に大きい値」、「ワイルドカード検索」は使えません| 値 | 内容 |
|---|---|
| 0 | 完全一致（通常はこちら） |
| -1 | 完全一致、なければ次に小さい値 |
| 1 | 完全一致、なければ次に大きい値 |
| 2 | ワイルドカード検索 |
第六引数「検索モード」
第六引数は、検索する順番を指定します。
バイナリ検索は大量データ向けの高速検索機能で、使用するには条件があるため通常は「使用しない」または「-1 ： 下から検索」だけ覚えれば十分です。
| 値 | 内容 |
|---|---|
| 1 | 上から検索（既定値） |
| -1 | 下から検索 |
| 2 | 昇順バイナリ検索 |
| -2 | 降順バイナリ検索 |
よくある質問
XLOOKUP が使えません
XLOOKUP は Excel 2019 以前では利用できません。
Microsoft 365、Excel 2021 以降であれば使用可能です。
古いバージョンの Excel を使用している場合は、VLOOKUP や INDEX / MATCH 関数を利用する必要があります。
お客様や社内などでファイルを共有する場合は、相手の Excel バージョンも確認しておきましょう。
※ Excel 2019 は 2025年10月14日 でサポート終了となっています。
VLOOKUP とどちらを使えばいいですか？
新しく作成する Excel ファイルであれば、XLOOKUP がおすすめです。
既存のファイルでは VLOOKUP が使われていることも多いため、両方の使い方を覚えておくと役立ちます。
まとめ
XLOOKUP は、VLOOKUP よりも使いやすく、柔軟にデータ検索ができる関数です。
特に、
・ 左端以外での検索
・ エラー処理
・ 下からの検索
・ 列追加に強い
といったメリットがあります。
これから新しく Excel ファイルを作成する場合は、XLOOKUP を活用することで、保守しやすく分かりやすい数式を作成できるでしょう。